- TI nspire
[프로그램] splitor, sor. "or" 단위로 구분된 수식을 "리스트 / 매트릭스 / 변수 " 형태로 바꿈
-
- 2024.06.22 - 12:47 2024.06.20 - 09:25 298 7
Define LibPub splitor(expression)=
Prgm
:Local i,pos,prev_pos,num_or,len
:len:=dim(string(expression))
:num_or:=0
:prev_pos:=1
:
:While prev_pos≤len
: pos:=inString(string(expression)," or ",prev_pos)
: If pos=0 Then
: Exit
: Else
: num_or:=num_or+1
: prev_pos:=pos+4
: EndIf
:EndWhile
:
:r.list:=newList(num_or+1)
:
:prev_pos:=1
:For i,1,num_or
: pos:=inString(string(expression)," or ",prev_pos)
: r.list[i]:=expr(mid(string(expression),prev_pos,pos-prev_pos))
: expr("r.e"&string(i)&":=r.list["&string(i)&"]")
: prev_pos:=pos+4
:EndFor
:
:r.list[num_or+1]:=expr(mid(string(expression),prev_pos,len-prev_pos+1))
:expr("r.e"&string(num_or+1)&":=r.list["&string(num_or+1)&"]")
:
:list▶mat(r.list,1)→r.matrix
:
:Disp "Number of 'or's: ",num_or
:Disp "Saved result as 'r.list' & 'r.matrix' & r.#num"
:Disp r.matrix
:
:EndPrgm
이 프로그램은 solve() 등에 의해 만들어진 수식(expression)에서 " or "을 기준으로 조건을 분리하고, 각 조건을 처리하여 결과를 저장하는 기능을 수행합니다. 프로그램의 각 부분을 이해하기 위해 다음과 같은 과정을 거칩니다:
-
변수 초기화 및 설정:
len: 수식의 길이를 저장합니다.num_or: " or "의 등장 횟수를 저장할 변수로 초기화합니다.prev_pos: 수식을 검사할 때 사용할 시작 위치를 초기화합니다.
-
'or' 등장 횟수 세기:
While루프를 사용하여 수식을 처음부터 끝까지 검사합니다.inString함수를 사용하여 " or "의 등장 위치를 찾습니다.- 만약 등장 위치(pos)가 0이면, 더 이상 " or "이 없다는 것이므로 루프를 종료합니다.
- 등장 횟수를 세는
num_or를 증가시키고, 다음 검색을 위해prev_pos를 조정합니다.
-
조건을 저장할 리스트 초기화:
newList함수를 사용하여 조건을 저장할r.list리스트를 생성합니다.- 리스트의 크기는 " or "의 등장 횟수(num_or)에 1을 더한 값으로 설정합니다.
-
각 조건을 리스트에 저장:
- 다시
prev_pos를 1로 초기화하고For루프를 통해 각 " or "의 위치를 찾고, 해당 위치 이전부터 해당 위치까지의 부분 문자열을 추출합니다. - 추출한 부분 문자열을
expr함수를 사용하여 식으로 변환하여r.list리스트의 해당 위치(i)에 저장합니다. - 다음 검색을 위해
prev_pos를 조정합니다.
- 다시
-
결과 저장 및 출력:
r.list리스트를list▶mat함수를 사용하여r.matrix라는 이름의 행렬로 변환하여 저장합니다.- r.e1, r.e2... 변수에 개별 원소를 저장합니다.
- 결과 출력을 위해 "Number of 'or's: "와
num_or의 값을 출력합니다. - "Saved result as 'r.list' & 'r.matrix'"와
r.matrix의 내용을 출력하여 최종 결과를 사용자에게 표시합니다.
이 프로그램은 주어진 수식에서 " or "을 기준으로 여러 조건을 분리하고, 이를 적절히 처리하여 결과를 출력하는 기능을 가지고 있습니다.
이 프로그램에서 사용된 함수들을 간략히 설명드리겠습니다:
-
dim(string(expression)):dim함수는 인자로 전달된 배열 또는 문자열의 차원을 반환합니다.string(expression)은 수식을 문자열로 변환한 것이며, 이의 길이를 반환하여 수식의 전체 길이를 구합니다.
-
inString(string(expression), " or ", prev_pos):inString함수는 첫 번째 문자열에서 두 번째 문자열이 처음으로 나타나는 위치를 반환합니다.string(expression)에서 " or "이라는 문자열이prev_pos위치부터 시작하여 처음 발견된 위치를 반환합니다.- 발견되지 않을 경우 0을 반환합니다.
-
newList(num_or + 1):newList함수는 주어진 크기(num_or + 1)로 새로운 리스트를 생성합니다.- 여기서는 " or "의 등장 횟수(num_or)에 1을 더한 크기로 리스트를 생성하여 조건들을 저장할 준비를 합니다.
-
mid(string(expression), prev_pos, pos - prev_pos):mid함수는 문자열에서 지정된 범위의 부분 문자열을 추출합니다.string(expression)에서prev_pos위치부터pos - prev_pos길이만큼의 부분 문자열을 추출하여 각 조건을 식으로 변환합니다.
-
expr(...):expr함수는 문자열을 수식으로 변환하여 계산 가능한 형식으로 반환합니다.- 예를 들어, 문자열 "2 + 3"을
expr("2 + 3")으로 호출하면, 이는 숫자 5로 계산될 수 있습니다. - 프로그램에서는 수식을 문자열로 추출한 후
expr함수를 사용하여 각 조건을 계산 가능한 형태로 변환합니다.
-
list▶mat(r.list, 1):list▶mat함수는 리스트를 행렬로 변환하는 함수입니다.- 여기서는
r.list리스트를 1열로 행렬로 변환하여r.matrix라는 이름의 행렬에 저장합니다. - 이는 계산 결과를 보다 보기 쉬운 구조화된 형태로 저장하기 위해 사용됩니다.
이 함수들은 프로그램에서 문자열 처리, 검색, 데이터 구조 변환 등 다양한 기능을 수행하는 데 사용되었습니다.
[추가] 댓글에 있는 것처럼 sor(expression) 함수를 추가하였습니다.
코드만 다르고, 기능은 splitor(expression) 과 동일합니다.
생성되는 결과 변수도 동일하기 때문에 서로가 서로의 결과를 덮어씌워 저장할 수 있습니다.
-
25
댓글7
-
세상의모든계산기2024.06.20 - 09:30 #41850
1. 첨부 파일에 올려둔 splitor.tns 를 다운받아
2. 계산기 MyLib 폴더에 업로드하시고
3. Refresh Library 명령 (doc - 6 ?) 을 한번 실행하시면
4. 다른 파일에서도 splitor\splitor(수식) 명령으로 사용하실 수 있습니다.
-
세상의모든계산기
주의
다 잘 되는데... 딱 하나 안되는게 있네요.
조건문(Constraint)에 list[], matrix[]넣으니까 "Error: Invalid outside program" 에러가 나는군요.
이상하네요??????????????프로그램의 문제는 아니고, 그냥 | 조건문(Constraint) 과 "리스트/매트릭스" 조합에 문제가 있는 모양입니다.
"program" 이라고 딱 나와서 프로그램 문제인 줄 알았는데, 수동으로 만들어서 해 봐도 같은 문제가 발생합니다. -
1
세상의모든계산기
이것 때문에 변수 r.e1, r.e2, r.e3, ... ... 에 개별적으로 저장하도록 기능을 추가하였습니다.
-
세상의모든계산기
r.matrix 로 만든 것은
수식이 길어질 때는
가로로 쭉~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ 연결되어 나와서
(PC든 계산기든) 알아보기가 힘들기 때문에
세로로 하나씩 출력하여 한눈에 쉽게 확인하기 위한 것입니다.
r.list 로 만든 것은
matrix 의 경우 값을 불러내려면
r.matrix[1,1] 과 같은 형태로 입력해야 하는데,
list 의 경우
r.list[1] 로 보다 간단하기 때문입니다.
편한걸로 취사선택해 쓰시면 됩니다.
- 1
-
세상의모든계산기
Define LibPub sor(expression)= Prgm :Local remains,count_or :© Initialize variables :remains:=expression :count_or:=0 :r.list:={} : :© Main Loop :While part(remains,0)="or" : count_or:=count_or+1 : r.list:=augment(r.list,{part(remains,1)}) : remains:=part(remains,2) : expr("r.e"&string(count_or)&":=r.list["&string(count_or)&"]") :EndWhile :r.list:=augment(r.list,{remains}) :list▶mat(r.list,1)→r.matrix :expr("r.e"&string(count_or+1)&":=r.list["&string(count_or+1)&"]") : :© Display Result :Disp "Number of 'or's: ",count_or :Disp "Saved result as 'r.list' & 'r.matrix' & r.#num" :Disp r.matrix :EndPrgm본문의 splitor() 와 실행 결과는 동일합니다.
part() 명령어를 이용하여 프로그램을 단순화하였습니다.
세상의모든계산기 님의 최근 댓글
2번 사진 3개 사진 공통적으로 구석(corner) 에 증상이 있다는 특징이 있네요. 영상 찾아보니 이 가능성이 가장 높은 듯 합니다. https://www.youtube.com/watch?v=zxRBohepzwc ㄴ Liquid Crystal Leakage (액정 누설). ㄴ 손으로 밀어내니 주변으로 밀려나네요. 그래서 점으로 보이기도 하구요. 2025 10.29 500! 의 십진수 근사값 확인 500! = 1.22013682599111006870123878542304692625357434280319284219241358838 × 10^(1134) (참값, 울프람 알파) 2025 10.29 관련 라이브러리 https://allcalc.org/56263 sgn(x) 내장된 부호 함수(signum function)와 달리, 이 함수의 sgn(0)은 0을 반환합니다. 2025 10.29 라이브러리로 사용할 수 있습니다. (제작자 추천) 1. mylib 폴더에 넣기 2. Actions ➡️ library ➡️ refresh libraries 실행 하기 2025 10.29 ChatGPT-5 기호(÷, /, :) 자체는 의미적으로 같은 “나눗셈”을 뜻하지만, 문맥(사람이 쓰는 수학 vs 컴퓨터/프로그래밍)에 따라 해석 우선순위가 달라질 수 있습니다. 🔹 1️⃣ 전통 수학 표기 — ÷, /, : 수학 교과서, 논문, 일반 문서 등에서는 셋 다 의미적으로 “나누기”로 간주됩니다. 즉, 48÷2(9+3), 48/2(9+3), 48:2(9+3) 은 같은 의미로 받아들여야 합니다. 모두 사람의 수학 관행적 해석이 적용되어 48 ÷ 2 × (9+3) = 288 로 처리되죠. 즉, 기호가 바뀌어도 결과는 바뀌지 않습니다. 🔹 2️⃣ 컴퓨터·프로그래밍 문맥에서 / 사용 시 컴퓨터는 “생략된 곱셈(implicit multiplication)”을 따로 구분하지 못합니다. 따라서 다음 두 식은 완전히 다르게 인식됩니다. 표현 파이썬 등에서 해석 결과 48 / 2*(9+3) ((48 / 2) * (9+3)) 288 48 / 2(9+3) ❌ 문법 오류 (생략된 곱셈 인식 불가) — 즉, 컴퓨터 언어에서는 생략된 곱셈이 허용되지 않기 때문에, /는 반드시 명시적 *와 함께 써야 합니다. 🔹 3️⃣ “:” 기호의 경우 현대 수학에서는 “비율”을 나타내는 기호로 쓰입니다. a:b = \frac{a}{b} 따라서 (27 : 3(1+2)3) 같은 표현은 모호하거나 비표준적으로 간주됩니다. 대부분의 경우 계산기로는 입력 자체가 불가능합니다. ✅ 정리 기호 의미 결과 변화 주로 쓰이는 문맥 ÷ 나누기 없음 초중등 수학, 일반 표기 / 나누기 없음 (단, 프로그래밍에서는 생략 곱 불허) 수학/컴퓨터 : 비율 (또는 나누기 의미로 혼용) 보통 계산식에서는 사용 안 함 비, 비율 표기 🔹 결론 48 ÷ 2(9+3), 48/2(9+3), 48:2(9+3) 는 “수학적 의미”로는 동일하게 81로 해석됩니다. 하지만 프로그래밍이나 수식 파서(context) 에서는 /만 유효하고, 생략된 곱은 허용되지 않으며, :는 아예 다른 의미(비율)로 인식됩니다. 2025 10.28